Colección de cadenas que son subcoincidencias de una expresión regular.

Observaciones

Una colección SubMatches contiene cadenas de subcoincidencias individuales, y sólo se puede crear utilizando el método Execute del objeto RegExp. Las propiedades de la colección SubMatches son de sólo lectura.

Cuando se ejecuta una expresión regular, pueden resultar ninguno o más subcoincidencias cuando las subexpresiones están entre paréntesis. Cada elemento en la colección SubMatches es la cadena encontrada y capturada por la expresión regular.

El siguiente código muestra cómo obtener una colección SubMatches con una búsqueda de expresión regular y cómo tener acceso a cada miembro individual:

Function PruebaDeSubMatch(cadenaEntrada)
   Dim oExpReg, oCoincidencia, oMatches
   Set oExpReg = New RegExp
   ' Busca una dirección de correo electrónico (no es una Expresión regular perfecta)
   oExpReg.Pattern = "(\w+)@(\w+)\.(\w+)"
   ' Obtiene la colección Matches
   Set oCoincidencias = oExpReg.Execute(cadenaEntrada)
   ' Obtiene el primer elemento de la colección Matches
   Set oCoincidencia = oCoincidencias(0)
   ' Crea la cadena de resultado.
   ' El objeto Match es la coincidencia entera - dragon@xyzzy.com
   retStr = "La dirección de correo electrónico es: " & oCoincidencia & vbNewline
   ' Obtiene las partes subcoincidente de la dirección.
   retStr = retStr & "El alias de correo electrónico es: " & oCoincidencia.SubMatches(0)  ' dragon
   retStr = retStr & vbNewline
   retStr = retStr & "La organización es: " & oCoincidencia. SubMatches(1)' xyzzy
   PruebaDeSubMatch = retStr
End Function

MsgBox(PruebaDeSubMatch("Por favor envíe un correo electrónico a dragon@xyzzy.com. Gracias."))

Requisitos

Versión 5.5

Consulte también

Instrucción For Each...Next | Objeto Match | Colección Matches | Objeto Regular Expression (RegExp)