Función GetLocale

Devuelve el valor del Id. de configuración regional actual.

GetLocale()

Observaciones

Una configuración regional es un conjunto de información de preferencias del usuario que incluye su idioma, país o región y convenciones culturales. La configuración regional determina cosas como la apariencia del teclado, el orden de clasificación alfabética, así como los formatos de fecha, hora, número y moneda.

El valor de retorno puede ser cualquiera de los valores de 32 bits mostrados en el cuadro de Id. de configuración regional:

El siguiente ejemplo ilustra el uso de la función GetLocale. Para utilizar este código, pegue el ejemplo completo entre las etiquetas <BODY> de una página HTML estándar.

Escriba la fecha en formato para Reino Unido: <input type="text" id="UKDate" size="20"><p>
Aquí tiene la equivalencia para EE.UU.: <input type="text" id="USdate" size="20"><p>
<input type="button" value="Convertir" id="button1"><p>
Escriba un precio en marcos alemanes: &nbsp; <input type="text" id="GermanNumber" size="20">
<p>
Aquí tiene la equivalencia en libras esterlinas: <input type="text" id="USNumber" size="20"><p>
<input type="button" value="Convertir" id="button2"><p>

<script language="vbscript">
Dim configRegionalactual
' Obtiene la configuración regional actual
configRegionalactual = GetLocale

Sub Button1_onclick
   Dim original
   original = SetLocale("en-gb")
   miFecha = CDate(UKDate.value)
   ' IE establece siempre la configuración regional como Inglés EE.UU.,
   ' así pues, use la variable configRegionalactual para establecer la 
   ' configuración regional como Inglés EE.UU.
   original = SetLocale(configRegionalactual)
   USDate.value = FormatDateTime(miFecha,vbShortDate)
End Sub

Sub button2_onclick
   Dim original
   original = SetLocale("de")
   miValor = CCur(GermanNumber.value)
   original = SetLocale("en-gb")
   USNumber.value = FormatCurrency(miValor)
End Sub

</script>

Consulte también

Función SetLocale | Cuadro de Id. de configuración regional (LCID)