Repite un bloque de instrucciones mientras una condición es True o hasta que una condición sea True.

Do [{While | Until} condición]
    [instrucciones]
    [Exit Do]
    [instrucciones]
Loop

O bien, puede utilizar esta sintaxis:

Do
    [instrucciones]
    [Exit Do]
    [instrucciones]
Loop [{While | Until} condición]

Argumentos

condición

Expresión numérica o de cadena que es True o False. Si la condición es Null, la condición se trata como False.

instrucciones

Una o varias instrucciones que se repiten mientras la condición es o hasta que sea True.

Comentarios

Exit Do sólo se puede utilizar dentro de una estructura de control Do...Loop para proporcionar una forma alternativa de salida de un bucle Do...Loop. Se puede ubicar cualquier número de instrucciones Exit Do en cualquier lugar del bucle Do...Loop. A menudo se utiliza con la evaluación de alguna condición (por ejemplo, If...Then). Exit Do transfiere el control a la instrucción que aparece inmediatamente después de Loop.

Cuando se utiliza dentro de instrucciones Do...Loop anidadas, Exit Do transfiere el control al bucle que está anidado un nivel por encima del bucle donde tiene lugar.

El siguiente ejemplo ilustra el uso de la instrucción Do...Loop:

Do Until DefResp = vbNo
   MiNum = Int (6 * Rnd + 1)   ' Genera un número entero aleatorio entre 1 y 6.
   DefResp = MsgBox (MiNum & " ¿Desea otro número?", vbYesNo)
Loop

Dim Comprobar, Contador
Comprobar = True: Contador = 0      ' Inicializa las variables.
Do                            ' Bucle exterior.
   Do While Contador < 20     ' Bucle interior.
      Contador = Contador + 1      ' Incrementa el contador.
      If Contador = 10 Then      ' Si la condición es True...
         Comprobar = False  ' establece el valor del indicador como False.
         Exit Do         ' Sale del bucle interior.
      End If
   Loop
Loop Until Comprobar = False      ' Sale del bucle exterior inmediatamente.

Requisitos

Versión 1

Consulte también

Instrucción Exit | Instrucción For...Next | Instrucción While...Wend