Comprueba una firma digital incluida en una secuencia de comandos.

Objeto.VerifyFile (NombreArchivo, MostrarIU)

Argumentos

objeto

Scripting.Signer

NombreArchivo

Una cadena que contiene el nombre del archivo de comandos.

MostrarIU

Un valor de tipo booleano. Si el argumento MostrarIU es falso (False), el objeto Scripting.Signer determina si la firma se obtuvo de un origen de confianza, sin preguntar al usuario. Si es cierto (True), el objeto Scripting.Signer puede crear un cuadro de diálogo para preguntar al usuario acerca del origen de la firma, si no encuentra información suficiente para determinar su confiabilidad.

Nota   En algunos sistemas operativos, el sistema operativo también crea un cuadro de diálogo si el indicador está activado, el archivo es de confianza y aún no ha activado la opción "Confiar siempre…".

Ejemplo

El siguiente ejemplo muestra cómo comprobar una firma mediante las características de proceso de argumentos desde la línea de comandos.

<job>
<runtime>
<named name="archivo" helpstring="el archivo que se desea firmar" required="true" type="string"/>
<named name="IU" helpstring="muestra la interfaz de usuario si la secuencia de comandos no es de confianza" required="false"/>
</runtime>
<script language="vbscript">
Dim Firmar, Archivo, IU, Correcto
If Not WScript.Arguments.Named.Exists("archivo") Then
     WScript.Arguments.ShowUsage
     WScript.Quit
End If
Set Firmar = CreateObject("Scripting.Signer")
Archivo = WScript.Arguments.Named("archivo")
IU   = WScript.Arguments.Named.Exists("iu")
Correcto = Firmar.VerifyFile(Archivo, IU)
If Correcto Then
     WScript.Echo Archivo & " es de confianza."
Else
     WScript.Echo Archivo & " NO es de confianza."
End If
</script>
</job>

Consulte también

Objeto Scripting.Signer | Método Verify | Método Sign | Método SignFile | Comprobar una secuencia de comandos