Envía texto a un cuadro de mensaje o a la ventana de la consola de comandos.

objeto.Echo [Arg1] [,Arg2] [,Arg3] ... 

Argumentos

objeto

Objeto WScript.

Arg1, Arg2, Arg3 ...

Opcional. Una cadena que indica la lista de elementos que se mostrarán.

Comentarios

El método Echo presenta un comportamiento diferente según el motor de Windows Script Host (WSH) que se utilice.

Cada elemento mostrado se separa mediante un espacio. Cuando se utiliza CScript.exe, como separador se usa un carácter de nueva línea. Si no se indica ningún elemento como argumento del método Echo, el resultado es una línea en blanco.

Ejemplo

El siguiente ejemplo utiliza el método Echo para mostrar el nombre del dominio, del equipo y del usuario del equipo actual, así como la información de asignación de las unidades e impresoras de red.

<package>
   <job id="vbs">
      <script language="VBScript">
         Set WshNetwork = WScript.CreateObject("WScript.Network")
         Set oDrives = WshNetwork.EnumNetworkDrives
         Set oPrinters = WshNetwork.EnumPrinterConnections
         WScript.Echo "Dominio = " & WshNetwork.UserDomain
         WScript.Echo "Nombre de equipo = " & WshNetwork.ComputerName
         WScript.Echo "Nombre de usuario = " & WshNetwork.UserName
         WScript.Echo 
         WScript.Echo "Unidades de red asignadas:"
         For i = 0 to oDrives.Count - 1 Step 2
            WScript.Echo "Unidad " & oDrives.Item(i) & " = " & oDrives.Item(i+1)
         Next
         WScript.Echo 
         WScript.Echo "Impresoras de red asignadas:"
         For i = 0 to oPrinters.Count - 1 Step 2
            WScript.Echo "Puerto " & oPrinters.Item(i) & " = " & oPrinters.Item(i+1)
         Next
      </script>
   </job>

   <job id="js">
      <script language="JScript">
         var WshNetwork = WScript.CreateObject("WScript.Network");
         var oDrives = WshNetwork.EnumNetworkDrives();
         var oPrinters = WshNetwork.EnumPrinterConnections();
         WScript.Echo("Dominio = " + WshNetwork.UserDomain);
         WScript.Echo("Nombre de equipo = " + WshNetwork.ComputerName);
         WScript.Echo("Nombre de usuario = " + WshNetwork.UserName);
         WScript.Echo();
         WScript.Echo("Unidades de red asignadas:");
         for(i=0; i<oDrives.Count(); i+=2){
            WScript.Echo("Unidad " + oDrives.Item(i) + " = " + oDrives.Item(i+1));
         }
         WScript.Echo();
         WScript.Echo("Impresoras de red asignadas:");
         for(i=0; i<oPrinters.Count(); i+=2){
            WScript.Echo("Puerto " + oPrinters.Item(i) + " = " + oPrinters.Item(i+1));
         }
      </script>
   </job>
</package>

Consulte también

Ejecutar sus secuencias de comandos | Objeto WScript