Introducción a Windows Script Host

La siguiente introducción explica cómo un administrador de red u otro profesional de tecnologías de la información (TI) puede utilizar Windows Script Host 5.6 para crear procedimientos que realicen tareas útiles.

Nota Esta introducción está escrita en VBScript. EL proceso que deben seguir los programadores para crear estas secuencias de comandos es prácticamente igual en VBScript y en JScript.

En esta introducción realizará las siguientes actividades:

Crear una secuencia de comandos que cree un recurso compartido común en varios equipos remotos y lo llene con archivos.
Crear una secuencia de comandos que cree una conexión común con un dispositivo de impresión y lo configure como dispositivo de impresión predeterminado.

Para poder finalizar la introducción, todos los equipos remotos deben estar configurados para poder ejecutar WSH remoto. Para obtener más información acerca de cómo habilitar esta configuración de seguridad, consulte Configurar WSH remoto.

Nota El código que se incluye a continuación pertenece al ejemplo que acompaña a esta documentación. Si desea ver el ejemplo completo, consulte Ejemplo de secuencia de comandos de WSH para un administrador de red.

Crear variables y constantes

Para crear las variables y constantes necesarias

En el programa que utilice para modificar las secuencias de comandos, escriba las variables.

Dim FSO
Dim Servicios
Dim SecDescClase
Dim SecDesc
Dim Confianza
Dim ACE
Dim Recurso
Dim InParam
Dim Red

A continuación, escriba las constantes en el procesador, pero cambie los valores por los correspondientes a los nombres y rutas de acceso UNC de su entorno de red.
```
Const NombreCarpeta = "C:\Public"
Const ServidorAdmin = "\\EquipoAdmin"
Const NombreRecurso = "Pubs"
Const RecursoImpresora = "\\ImpresorasCorp\RecursoImpresora"
```

Conectar con una impresora y configurarla como predeterminada

Para conectar el equipo a un dispositivo de impresión

En el programa que utilice para modificar las secuencias de comandos, escriba el código necesario para crear un dispositivo de impresión. Este código utiliza la variable Red y la constante RecursoImpresora que se inicializaron en el paso anterior.
```
Set Red = CreateObject("WScript.Network")    
Red.AddWindowsPrinterConnection RecursoImpresora
```

Para configurar el dispositivo de impresión predeterminado para un equipo

En el programa que utilice para modificar las secuencias de comandos, escriba el código necesario para configurar el dispositivo de impresión predeterminado. Este código utiliza la variable Red y la constante RecursoImpresora que se inicializaron en el primer paso.
```
Red.SetDefaultPrinter RecursoImpresora
```

Crear un recurso compartido, copiar archivos en él y compartirlo

Para crear un recurso compartido en el equipo

En el programa que utilice para modificar las secuencias de comandos, escriba el código necesario para crear un Objeto del sistema de archivos (FSO, File System Object) y una carpeta. La secuencia de comandos comprueba si existe la carpeta. Si no existe, la crea. Este código utiliza la variable FSO y la constante RecursoImpresora que se inicializaron en el primer paso.
```
Set FSO = CreateObject("Scripting.FileSystemObject")
If Not FSO.FolderExists(NombreCarpeta) Then 
   FSO.CreateFolder(NombreCarpeta)
End If
```

Para copiar archivos en la carpeta recién creada

En el programa que utilice para modificar las secuencias de comandos, escriba el código necesario para crear un Objeto del sistema de archivos (FSO) y copiar los archivos del equipo local al remoto. Este código utiliza la variable FSO y la constante RecursoImpresora que se inicializaron en el primer paso.
```
Call FSO.CopyFile(ServidorAdmin & "\Public\Imagenes\*.*", NombreCarpeta)
```

Para utilizar WMI para configurar la nueva carpeta como un recurso compartido

En el programa que utilice para modificar las secuencias de comandos, escriba el código necesario para crear un recurso compartido mediante el Instrumental de administración de Windows (WMI). El recurso compartido se configura en la carpeta creada anteriormente. Lo primero que hace la secuencia de comandos es conectarse con WMI. A continuación, establece el nivel de representación de seguridad y los privilegios de Windows NT que permiten configurar Listas de control de acceso discrecional (DACL) y Listas de control de acceso de seguridad (SACL). Después crea un nuevo descriptor de seguridad y configura un par de Entradas de control de acceso (ACE) para el nuevo recurso compartido. Por último, crea un nuevo recurso compartido con el nuevo descriptor de seguridad. En el código se utilizan las variables Servicios, SecDescClase, SecDesc, Confianza, ACE, Recurso y InParam, y las constantes NombreCarpeta, RecursoAdmin y NombreRecurso que se inicializaron en el primer paso.
Nota WMI es una tecnología eficaz y sofisticada basada en Web Based Enterprise Management (WBEM). WMI se utiliza principalmente para la instrumentación y el acceso a la información de administración de un entorno empresarial. Para obtener más información acerca de WMI, consulte Microsoft Windows Management Instrumentation: Background and Overview, en la dirección (http://msdn.microsoft.com/library/default.asp?URL=/library/backgrnd/html/wmixwdm.asp).
```
Set Servicios = GetObject("WINMGMTS:{impersonationLevel=impersonate,(Security)}!" & ServidorAdmin & "\ROOT\CIMV2")
Set SecDescClase = Servicios.Get("Win32_SecurityDescriptor")
Set SecDesc = SecDescClase.SpawnInstance_()
Set Confianza = Servicios.Get("Win32_Trustee").SpawnInstance_
Confianza.Domain = Null
Confianza.Name = "EVERYONE"
Confianza.Properties_.Item("SID") = Array(1, 1, 0, 0, 0, 0, 0, 1, 0, 0, 0, 0)
Set ACE = Servicios.Get("Win32_Ace").SpawnInstance_
ACE.Properties_.Item("AccessMask") = 2032127
ACE.Properties_.Item("AceFlags") = 3
ACE.Properties_.Item("AceType") = 0
ACE.Properties_.Item("Trustee") = Confianza
SecDesc.Properties_.Item("DACL") = Array(ACE)
Set Recurso = Servicios.Get("Win32_Share")
Set InParam = Recurso.Methods_("Create").InParameters.SpawnInstance_()
InParam.Properties_.Item("Access") = SecDesc
InParam.Properties_.Item("Description") = "Recurso compartido público"
InParam.Properties_.Item("Name") = NombreRecurso
InParam.Properties_.Item("Path") = NombreCarpeta
InParam.Properties_.Item("Type") = 0
Share.ExecMethod_("Create", InParam)
```

Ejecutar la secuencia de comandos completa

El ejemplo que se incluye en esta documentación contiene una secuencia de comandos completa, que se puede ejecutar para realizar todas las funciones anteriores. Consulte Ejemplo de secuencia de comandos de WSH para un administrador de red.

Antes de ejecutar la secuencia de comandos, asegúrese de que todos los equipos están configurados correctamente para ejecutar secuencias de comandos remotas. Para ello, utilice Poledit.exe desde el servidor. Para obtener más información, consulte Configurar WSH remoto.

Cuando se ejecuta un WSH remoto, la secuencia de comandos se copia en los equipos remotos. Después de comprobar la configuración de seguridad del equipo remoto y copiar la secuencia de comandos, un código de retorno indica si el proceso se realizó correctamente o no. Si se llevó a cabo correctamente, la secuencia de comandos se ejecuta en los equipos remotos. Para obtener más información acerca de cómo ejecutar una secuencia de comandos de WSH remoto, consulte Ejecutar secuencias de comandos de forma remota.

Consulte también

Configurar WSH remoto | Acceso a redes | Ejecutar secuencias de comandos de forma remota